aprenda chute
logo3d
atribua "s 2			;escala (pixel / unid. comprimento)
desapareçatat
ativetartaruga -1		;ponto de vista:
mudexyz 0 -200*:s 100*:s	;  visto de lado
;mudexyz 0 0 200*:s		;  visto de cima
ativetartaruga 0
jalisco
atribua "vcrise 23.8         	;velocidade de crise
atribua "ro 1.224	      	;densidade do ar ao nivel do mar (kg/m3)
atribua "g 9.8			;aceleracao da gravidade (m/s2)
atribua "m 0.43 		;massa da bola (kg)
atribua "r 0.11			;raio da bola (m)
atribua "c0 0.5			;coeficiente de arrasto sem crise
atribua "c1 0.1			;coeficiente de arrasto com crise
atribua "cm 1.0			;coeficiente de magnus
atribua "area pi*:r*:r
atribua "b0 :c0*:ro*:area/2/:m
atribua "b1 :c1*:ro*:area/2/:m
atribua "mag :cm*:ro*:area*pi*:r/:m
atribua "h 0.001			;intervalo de tempo 
condini     				;condicoes iniciais
usenada
mudexyz (:x*:s) (:y*:s) (:z*:s)
uselápis				;calcula e desenha a trajetoria
façaenquanto [passo] [:z>0]
(escreva "t= :t)
(escreva [(x y z) =] :x :y :z)
fim

aprenda condini
atribua "x 20.0			;condicoes iniciais
atribua "y 0.0
atribua "z 0.00
atribua "t 0.0
atribua "vx 25.0
atribua "vy -9.0
atribua "vz 9.0
atribua "fx 0.0
atribua "fy 0.0
atribua "fz 10
fim

aprenda jalisco 
mudecl [0 150 0]
usenada
mudexyz 0 0 0			;meio de campo
uselápis
arco 360 9.15*:s 		;grande circulo
usenada
mudexyz 52.5*:s -34*:s 0	;linhas de fundo
uselápis
mudexyz 52.5*:s 34*:s 0
mudexyz -52.5*:s 34*:s 0
mudexyz -52.5*:s -34*:s 0
mudexyz 52.5*:s -34*:s 0
usenada
mudexyz 0 -34*:s 0		;linha central
uselápis
mudexyz 0 34*:s 0
usenada
mudexyz 52.5*:s (3.66+16.5)*:s 0		;grande area
uselápis
mudexyz (52.5-16.5)*:s  (3.66+16.5)*:s 0
mudexyz (52.5-16.5)*:s -(3.66+16.5)*:s 0
mudexyz 52.5*:s -(3.66+16.5)*:s 0
mudexyz 52.5*:s -(3.66+5.5)*:s 0 		;pequena area
mudexyz (52.5-5.5)*:s -(3.66+5.5)*:s 0
mudexyz (52.5-5.5)*:s  (3.66+5.5)*:s 0
mudexyz 52.5*:s (3.66+5.5)*:s 0 
usenada
mudexyz -52.5*:s (3.66+16.5)*:s 0		;grande area
uselápis
mudexyz -(52.5-16.5)*:s  (3.66+16.5)*:s 0
mudexyz -(52.5-16.5)*:s -(3.66+16.5)*:s 0
mudexyz -52.5*:s -(3.66+16.5)*:s 0
mudexyz -52.5*:s -(3.66+5.5)*:s 0		;pequena area
mudexyz -(52.5-5.5)*:s -(3.66+5.5)*:s 0
mudexyz -(52.5-5.5)*:s  (3.66+5.5)*:s 0
mudexyz -52.5*:s (3.66+5.5)*:s 0
usenada
mudexyz (52.5-11)*:s 0 0			;marca de penalti
uselápis
pd 90
arco  (arccos 5.5/9.15) 9.15*:s 		;meialua
arco -(arccos 5.5/9.15) 9.15*:s
usenada
mudexyz -(52.5-11)*:s 0 0			;marca de penalti
uselápis
pe 180
arco  (arccos 5.5/9.15) 9.15*:s 		;meialua
arco -(arccos 5.5/9.15) 9.15*:s
pd 90
usenada
mudecl [0 0 0]
mudexyz -52.5*:s -3.66*:s 0			;trave
uselápis
mudexyz -52.5*:s -3.66*:s 2.44*:s
mudexyz -52.5*:s  3.66*:s 2.44*:s
mudexyz -52.5*:s  3.66*:s 0
usenada
mudexyz 52.5*:s -3.66*:s 0			;trave
uselápis
mudexyz 52.5*:s -3.66*:s 2.44*:s
mudexyz 52.5*:s  3.66*:s 2.44*:s
mudexyz 52.5*:s  3.66*:s 0
fim

aprenda aceleração
atribua "modv raizq(:vx*:vx+:vy*:vy+:vz*:vz)
senão (:modv<:vcrise)~
   [atribua "b :b0  atribua "cor [0 0 255]]~
   [atribua "b :b1  atribua "cor [255 0 0]]
mudecl :cor 
atribua "ax -(:b*:vx*:modv) + :mag*:vz*:fy - :mag*:vy*:fz
atribua "ay -(:b*:vy*:modv) + :mag*:vx*:fz - :mag*:vz*:fx
atribua "az -(:b*:vz*:modv) + :mag*:vy*:fx - :mag*:vx*:fy - :g
fim

aprenda passo
aceleração 				;calcula ax e az
atribua "vx :vx + :ax*:h  		;passo pelo metodo de Euler-Cromer
atribua "vy :vy + :ay*:h
atribua "vz :vz + :az*:h
atribua "x :x + :vx*:h		
atribua "y :y + :vy*:h		
atribua "z :z + :vz*:h
atribua "t :t + :h
mudexyz (:x*:s) (:y*:s) (:z*:s)		;move a tartaruga
fim